G1 CALCULATION GROUP MZ Correlations DOC Depression -> Smoking model
Calculation NG=6
MATRICES
A Di 2 2 Free
C Di 2 2 Free
E Di 2 2 Free
B Fu 2 2
I Id 2 2 
End Matrices;

Specify B
0 0
7 0

Start .6 all

begin algebra;
X = A*A' ;
Y = C*C' ;
Z = E*E' ;
R =      ( (I@((I-B)~))*( X+Y+Z| X+Y _
                            X+Y| X+Y+Z) * (I@((I-B)~)') ) ;
end algebra;

Option RS
End 

G2 CALCULATION GROUP DZ Correlation matrix 
Calculation
MATRICES=Group 1
H Fu 1 1 ! .5
End Matrices;

Matrix H .5

begin algebra;
X = A*A' ;
Y = C*C' ;
Z = E*E' ;
R =      ( (I@((I-B)~)) *( X+Y+Z| H@X+Y _
                           H@X+Y| X+Y+Z) * (I@((I-B)~)') ) ;
end algebra;
Option RS 
End

G3 MZ data
Data NI=4 NO=415
la S1 D1 S2 D2
km
1.0
0.24 1.00
0.81 0.24 1.00
0.24 0.49 0.24 1.00
matrices
r full 4 4 =R1 ! correlation matrix A1B1A2B2
end matrices;
cov r /
end

G4 DZ data
Data NI=4 NO=310
la S1 D1 S2 D2
km
1.0
0.45 1.00
0.54 0.30 1.00
0.30 0.23 0.45 1.00
matrices
r full 4 4 =R2 ! correlation matrix A1B1A2B2
end matrices;
cov r /
end

G5 Constrain a^2 + c^2 + e^2 =1
Constraint Ni=1
Begin Matrices = Group 1
End Matrices
Constraint \d2v(I) = \d2v(X+Y+Z) ;
End Group

Group 6 - standardize estimates
Data calc
matrices
A Di 2 2 = A1
C Di 2 2 = C1
E Di 2 2 = E1
B Fu 2 2 = B1
I Id 2 2
H Fu 1 1 ! .5
J iden 4 4
begin algebra;
X = A*A' ;
Y = C*C' ;
Z = E*E' ;
K = I@((I-B)~);
L =  \v2d(\sqrt(\d2v((I@((I-B)~))*( X+Y+Z| X+Y _
                              X+Y| X+Y+Z)* (I@((I-B)~)'))));
M = L~*K*L;
R = \d2v(X+Y+Z);
S = ((\d2v(X))%R)_((\d2v(Y))%R)_((\d2v(Z))%R);
end algebra;
compute M;
Labels row S
A_A A_B C_A C_B E_A E_B
labels row L
MZT1Abeta MZT1Bbeta
MZT1Abeta MZT1Bbeta
! fix all
option rs nd=8 
! option nag=10 db=1
end